Lines and source formats

A line is a horizontal arrangement of characters. A column is a vertical arrangement of characters, where each character, or each byte of a multibyte character, in a given column shares the same horizontal line position.

Because XL Fortran measures lines in bytes, these definitions apply only to lines containing single-byte characters. Each byte of a multibyte character occupies one column.

The kinds of lines are:

Fixed source form

Except within a character context, white space is insignificant. You can embed white space between and within lexical tokens, without affecting the way the compiler treats them.

Tab formatting means that there is a tab character in columns 1 through 6 of an initial line in XL Fortran, which directs the compiler to interpret the next character as being in column 7.

Requirements for lines and for items on those lines are:

• A comment line begins with a C, c, or an asterisk (*) in column 1, or is all white space. Comments can also follow an exclamation mark (!), except when the exclamation mark is in column 6 or in a character context.
• For an initial line without tab formatting:
  • Columns 1 through 5 contain either blanks, a statement label, a D or an X in column 1 optionally followed by a statement label.
  • Column 6 contains a blank or zero.
  • Columns 7 through to the right margin contain statement text, possibly followed by other statements or by an inline comment.
• For an initial line with tab formatting in XL Fortran:
  • Columns 1 through 6 begin with either blanks, a statement label, or a D or an X in column 1, optionally followed by a statement label. You must follow this with a tab character.
  • If you specify the -qxflag=oldtab compiler option, all columns from the column immediately following the tab character through to the right margin contain statement text, possibly followed by other statements and by an inline comment.
  • If you do not specify -qxflag=oldtab compiler option, all columns from column 7, which corresponds to the character after the tab, to the right margin contain statement text, possibly followed by other statements and by an inline comment.
• For a continuation line:
  • Column 1 must not contain C, c, or an asterisk. Columns 1 through 5 must not contain an exclamation mark as the leftmost nonblank character.
    IBM Extension

    Column 1 can contain a D or an X which signifies a debug line in XL Fortran. Otherwise, these columns can contain any characters allowed in a character context; these characters are ignored.

    End of IBM Extension
  • Column 6 must contain either a nonzero character or a nonwhite space character. The character in column 6 is the continuation character. Exclamation marks and semicolons are valid continuation characters.
  • Columns 7 through to the right margin contain continued statement text, possibly followed by other statements and an inline comment.
  • Neither the END statement or a statement whose initial line appears to be a program unit END statement can be continued.

A semicolon separates statements on a single source line, except when appearing in a character context, in a comment, or in columns 1 through 6. Two or more semicolon separators that are on the same line and are themselves separated by only white space or other semicolons are considered to be a single separator. A separator that is the last character on a line or before an inline comment is ignored. Statements following a semicolon on the same line cannot be labeled. Additional statements cannot follow a program unit END statement on the same line.

Debug lines

Example of fixed source form

C Column Numbers:
C        1         2         3         4         5         6         7
C23456789012345678901234567890123456789012345678901234567890123456789012

!IBM* SOURCEFORM (FIXED)
      CHARACTER CHARSTR ; LOGICAL X          ! 2 statements on 1 line
      DO 10 I=1,10
        PRINT *,'this is the index',I  ! with an inline comment
10    CONTINUE
C
       CHARSTR="THIS IS A CONTINUED
     X CHARACTER STRING"
       ! There will be 38 blanks in the string between "CONTINUED"
       ! and "CHARACTER". You cannot have an inline comment on
       ! the initial line because it would be interpreted as part
       ! of CHARSTR (character context).
  100 PRINT *, IERROR
! The following debug lines are compiled as source lines if
! you use -qdlines
D     IF (I.EQ.IDEBUG.AND.
D    +    J.EQ.IDEBUG)     WRITE(6,*) IERROR
D     IF (I.EQ.
D    +  IDEBUG )
D    +  WRITE(6,*) INFO
       END

Free source form

A free source form line can specify up to 132 characters on each line. In XL Fortran, there is no limit to the number of continuation lines for a statement , but the statement cannot be longer than 34 000 characters. Fortran 2003 limits the number of continuation lines to 255, while Fortran 95 limits the number of continuation lines to 39.

Items can begin in any column of a line, subject to the following requirements for lines and items on those lines:

• A comment line is a line of white space or begins with an exclamation mark that is not in a character context.
• An initial line can contain any of the following items, in the following sequence:
  • A statement label.
  • Statement text. Note that statement text is required in an initial line.
  • Additional statements.
  • The ampersand continuation character.
  • An inline comment.
• If you want to continue an initial line or continuation line in a non-character context, the continuation line must start on the first noncomment line that follows the intial line or continuation line. To define a line as a continuation line, you must place an ampersand after the statements on the previous non-comment line.
• White space before and after the ampersand is optional, with the following restrictions:
  • If you also place an ampersand in the first nonblank character position of the continuation line, the statement continues at the next character position following the ampersand.
  • If a lexical token is continued, the ampersand must immediately follow the initial part of the token, and the remainder of the token must immediately start after the ampersand on the continuation line.
• A character context can be continued if the following conditions are true:
  • The last character of the continued line is an ampersand and is not followed by an inline comment. If the rightmost character of the statement text to be continued is an ampersand, you must enter a second ampersand as a continuation character.
  • The first nonblank character of the next noncomment line is an ampersand.

A semicolon separates statements on a single source line, except when the semicolon appears in a character context or in a comment. Two or more separators that are on the same line and are themselves separated by only white space or other semicolons are considered to be a single separator. A separator that is the last character on a line or before an inline comment is ignored. Additional statements cannot follow a program unit END statement on the same line.

White space

White space must not appear within lexical tokens, except in a character context or in a format specification. You can freely insert white space between tokens to improve readability, and white space must separate names, constants, and labels from adjacent keywords, names, constants, and labels.

Certain adjacent keywords can require white space. The following table lists keywords where white space is optional..

Example of free source form

!IBM* SOURCEFORM (FREE(F90))
!
! Column Numbers:
!        1         2         3         4         5         6         7
!23456789012345678901234567890123456789012345678901234567890123456789012
 DO I=1,20
   PRINT *,'this statement&
   & is continued' ; IF (I.LT.5) PRINT *, I

 ENDDO
 EN&
         &D              ! A lexical token can be continued

IBM free source form

An IBM® free source form line or statement is a sequence of up to 34000 characters. Items can begin in any column of a line, subject to the following requirements:

• A comment line begins with a double quotation mark in column 1, is a line of all white space, or is a zero-length line. A comment line must not follow a continued line. Comments can follow an exclamation mark except in a character context.
• An initial line can contain any of the following items, in the following sequence:
  • A statement label
  • Statement text
  • The minus sign continuation character
  • An inline comment
• A continuation line immediately follows a continued line and can contain any of the following items, in the following sequence:
  • Statement text
  • A continuation character
  • An inline comment

If statement text on an initial line or continuation line is to continue, a minus sign indicates continuation of the statement text on the next line. In a character context, if the rightmost character of the statement text to continue is a minus sign, a second minus sign must be entered as a continuation character.

Except within a character context, white space is insignificant. You can embed white space between and within lexical tokens, without affecting how the compiler treats those tokens.

Example of IBM free source form

!IBM* SOURCEFORM (FREE(IBM))
"
" Column Numbers:
"        1         2         3         4         5         6         7
"23456789012345678901234567890123456789012345678901234567890123456789012
 DO I=1,10
  PRINT *,'this is -
             the index',I   ! There will be 14 blanks in the string
                            ! between "is" and "the"
 END DO
 END

Conditional compilation

You can use sentinels to mark specific lines of an XL Fortran program for conditional compilation. This allows you to port code that contains statements that are only valid or applicable in an SMP environment to a non-SMP environment.

Syntax for conditional compilation

>>-cond_comp_sentinel--fortran_source_line---------------------><
 

cond_comp_sentinel

is a conditional compilation sentinel defined by the current source form and is either:

• !$, C$, c$, or *$, for fixed source form, or
• !$, for free source form

fortran_source_line

is an XL Fortran source line

Conditional compilation rules

General rules

A valid XL Fortran source line must follow the conditional compilation sentinel.

A conditional compilation line can contain the EJECT, INCLUDE or noncomment directives.

A conditional compilation sentinel must not contain embedded white space.

A conditional compilation sentinel must not follow a source statement or directive on the same line.

If you are continuing a conditional compilation line, the conditional compilation sentinel must appear on at least one of the continuation lines or on the initial line.

You must specify the -qcclines compiler option for conditional compilation lines to be recognized. To disable recognition of conditional compilation lines, specify the -qnocclines compiler option.

Trigger directives take precedence over conditional compilation sentinels. For example, if you specify the -qdirective='$' option, then lines that start with the trigger, such as !$, will be treated as comment directives, rather than conditional compilation lines.

Fixed source form rules

Conditional compilation sentinels must start in column 1.

All rules for fixed source form line length, case sensitivity, white space, continuation, tab formatting, and columns apply.

Free source form rules

Conditional compilation sentinels can start in any column.

All rules for free source form line length, case sensitivity, white space, and continuation apply. When you enable recognition of conditional compilation lines, the conditional compilation sentinel two white spaces replace the conditional compilation sentinel.