As an example of displaying data, suppose an application program with an ACB name of APPLA compares the number of active local contention-winner sessions with the session limits value controlling the minimum number of contention-winner sessions guaranteed to the application program. Assume that the partner LU is APPLB and the mode is EXAMPLE. The following code might be used to issue the APPCCMD CONTROL=OPRCNTL, QUALIFY=DISPLAY macroinstruction to retrieve the information:

         LA    9,RPLA              * GET RPL ADDRESS
         LA    11,RPLAX            * GET RPL EXTENSION ADDRESS
         LA    10,CBAREA           * GET CONTROL BLOCK ADDRESS
         USING ISTSLD,10           * ESTABLISH ADDRESSABILITY
         L     8,CBLEN             * GET CONTROL BLOCK LENGTH
*
         APPCCMD CONTROL=OPRCNTL,                                      X
               QUALIFY=DISPLAY,                                        X
               RPL=(9),                                                X
               AAREA=(11),                                             X
               ACB=APPLA,                                              X
               OPTCD=SYN,                                              X
               LUNAME=APPLB,                                           X
               LOGMODE=EXAMPLE,                                        X
               AREA=(10),                                              X
               AREALEN=(8)
*
         LTR   15,15               * CHECK GENERAL RETURN CODE IN 15
         BNZ   BADGENRC            * HANDLE NONZERO RETURN CODE
         LTR   0,0                 * CHECK CONDITIONAL COMPLETION
         BNZ   BADCOND             * HANDLE NONZERO RETURN CODE
         CLC   SLDMCWL,SLDWINLC    * RETURN CODES OK - COMPARE VALUES
         BH    LOWROUT             * IF ACTUAL COUNT LESS, GO SOMEWHERE
         B     NOTLOW              * OTHERWISE, GO SOMEWHERE ELSE
           •
           •
           •
CBAREA   DS    XL68                * STORAGE FOR CONTROL BLOCK
         DS    0F                  * ALIGN TO FULLWORD BOUNDARY
CBLEN    DC    X'0000044'          * CONTROL BLOCK LENGTH
RPLA     RPL AM=VTAM               * RPL STORAGE
RPLAX    ISTRPL6                   * RPL EXTENSION STORAGE
APPLA    ACB AM=VTAM,MACRF=LOGON,APPLID=APPLNAME * ACB STORAGE