Suppose that an application program with an ACB name of APPLA is to establish a conversation with a partner LU known as APPLB. The conversation should use the EXAMPLE mode, and connect to a transaction program at APPLB known as INQUIRY_MANAGER. APPLA also includes PIP data on the allocation request of "INQUIRY=BALANCE CUSTOMER=899902".  The APPCCMD is issued synchronously, and the returned conversation identifier is stored by APPLA in the data area referenced by the CONVERID label. (Assume that the other fields in the FMH-5 used in this example were previously initialized properly and that a CNOS request has been successfully negotiated between the two LUs.)

         LA    10,FMH5STOR       * GET FMH-5 ADDRESS
         USING ISTFM5,10         * ESTABLISH ADDRESSABILITY
         MVI   FM5LNTPN,X'0F'    * SET TRANSACTION PROGRAM NAME LENGTH
         MVC   FM5TPNAM(15),=C'INQUIRY_MANAGER' * SET TP NAME
         OI    FM5FLAG2,FM5PIPPR * SET BIT TO INDICATE PIP PRESENT
         MVC   FM5TPNAM+15(3),=X'000000' * SET REST OF FMH5 TO ZEROS
         MVI   FM5LENTH,X'1C'    * SET LENGTH OF FMH5 WITHOUT PIP DATA
         LA    9,28(,10)         * SET ADDRESS OF START OF PIP DATA
         USING FM5PIPFM,9        * ESTABLISH ADDRESSABILITY
         LA    8,32(,10)         * SET ADDRESS OF PIP DATA SUBFIELD
         USING FM5PIPSM,8        * ESTABLISH ADDRESSABILITY
         MVC   FM5PIPLN,=X'0027' * SET LENGTH OF PIP SUBFIELDS AND DATA
         MVC   FM5PIPGD,=X'12F5' * SET PIP GDS ID IN FMH-5
         MVC   FM5PIPSL,=X'0023' * SET LENGTH OF PIP DATA SUBFIELD
         MVC   FM5PIPSG,=X'12E2' * SET SUBFIELD ID IN FMH-5
         MVC   FM5PIPSD(31),=C'INQUIRY=BALANCE CUSTOMER=899902' * DATA
         DROP  8,9               * DROP PIP DSECT REGISTERS
 
*
* FMH-5 AND PIP ARE SET.  NOW FOR THE APPCCMD.
*
         APPCCMD CONTROL=ALLOC,                                        X
               QUALIFY=ALLOCD,                                         X
               RPL=RPLA,                                               X
               AAREA=RPLAX,                                            X
               ACB=APPLA,                                              X
               LUNAME=APPLB,                                           X
               LOGMODE=EXAMPLE,                                        X
               OPTCD=SYN,                                              X
               AREA=(10),                                              X
               RECLEN=67
*
         LTR   15,15             * CHECK GENERAL RETURN CODE IN 15
         BNZ   BADGENRC          * HANDLE NONZERO RETURN CODE
         LTR   0,0               * CHECK CONDITIONAL COMPLETION
         BNZ   BADCOND           * HANDLE NONZERO RETURN CODE
         LA    8,RPLAX           * GET RPL EXTENSION ADDRESS
         USING ISTRPL6X,8        * ESTABLISH ADDRESSABILITY
         MVC   CONVERID,RPL6CNVD * STORE THE CONVERSATION ID
                  •
                  •
                  •
CONVERID DS    XL4               * RETURNED CONVERSATION ID
FMH5STOR DS    XL255             * FMH-5 AND PIP STORAGE
RPLA     RPL AM=VTAM             * RPL STORAGE
RPLAX    ISTRPL6                 * RPL EXTENSION STORAGE
APPLA    ACB AM=VTAM,MACRF=LOGON,APPLID=APPLNAME * ACB STORAGE