TITLE 'USER EXTENSION MODULE -- WSTRKGRP - WORK SELECTION C
ROUTINE FOR TRKGRP CRITERIA'
*************************************************************************
* *
* WSTRKGRP - WORK SELECTION ROUTINE TO COMPARE THE DCT'S *
* AND JQE'S NUMBER OF TRACK GROUPS *
* *
* FUNCTION: *
* *
* THIS ROUTINE WILL BE CALLED TO INSURE THAT THE JOB'S NUMBER *
* OF TRACK GROUPS IS EQUAL TO OR BEYOND THE DCT'S THRESHOLD. *
* *
* LINKAGE: *
* *
* BALR R14,15 TO BY HASPSERV *
* *
* ENVIRONMENT: *
* *
* THIS ENVIRONMENT IS CALL FROM THE JES2 MAIN TASK. *
* *
* RECOVERY: *
* *
* NONE. *
* *
* REGISTER USAGE (ENTRY/EXIT): *
* *
* REG VALUE ON ENTRY VALUE ON EXIT *
* *
* R0 N/A UNCHANGED *
* R1 N/A UNPREDICATABLE *
* R2 ADDR OF CRITERION BEING *
* PROCESSED UNCHANGED *
* R4-R5 N/A UNCHANGED *
* R6 N/A UNPREDICTABLE *
* R7 COMPARISON LENGTH UNPREDICTABLE *
* R8 ADDR OF DEVICE FIELD UNCHANGED *
* R9 N/A UNCHANGED *
* R10 ADDR OF COMPARISON FIELD UNCHANGED *
* R11 HCT BASE ADDRESS UNCHANGED *
* R12 N/A UNCHANGED *
* R13 PCE BASE ADDRESS UNCHANGED *
* R14 RETURN ADDRESS UNCHANGED *
* R15 ENTRY ADDRESS 0 *
* *
* PARAMETER LIST: *
* *
* NONE *
* *
* REGISTER USAGE (INTERNAL): *
* *
* REG VALUE *
* *
* R0 N/A *
* R1 ADDR OF JQE *
* R2 ADDR OF CRITERION BEING *
* PROCESSED *
* R4-R5 N/A *
* R6 N/A *
* R7 COMPARISON LENGTH *
* R8 ADDR OF DEVICE FIELD *
* R9 N/A *
* R10 ADDR OF COMPARISON FIELD *
* R11 HCT BASE ADDRESS *
* R12 N/A *
* R13 PCE BASE ADDRESS *
* R14 LINKAGE REGISTER *
* R15 LINKAGE REGISTER *
* *
* RETURN CODES (R15 ON EXIT): *
* *
* 4 - CONTINUE CRITERIA PROCESSING, ACCEPTABLE CONDITION *
* 12 - UNACCEPTABLE CONDITION, CRITERIA DO NOT MATCH *
* *
* OTHER CONSIDERATIONS: *
* *
* $SAVE AND $RETURN NOT USED FOR PERFORMANCE REASONS *
* *
*************************************************************************
SPACE 1
ENTRY WSTRKGRP ESTABLISH ENTRY POINT
USING WSTRKGRP,R6 ESTABLISH ADDRESSABILITY
USING PCE,R13 ESTABLISH PCE ADDRESSABILITY
SPACE 1
WSTRKGRP LR R6,R15 SET ADDRESSABILITY
BCTR R7,0 PREPARE LENGTH FOR EXECUTES
LR R15,R10 SET THE JQE FIELD ADDRESS
SL R15,=A(JQETGNUM-JQE) TO OBTAIN THE JQE ADDRESS
LR R1,R10 OBTAIN THE FIELD ADDRESS
TM JQEFLAG5-JQE(R15),JQE5XUSD NUM OF TGS IN EXT AREA...
BNO WSTTGN NO, GO DO COMPARISON
LH R1,JQETGNUM-JQE(,R15) GET THE OFFSET INTO EXT AREA
AL R1,$JQEEXT AND OBTAIN THE ADDRESS OF TGN
WSTTGN LA R15,12 ASSUME TG NO. NOT AT THRESHOLD
EX R7,WSTCLC TG NUMBER AT THRESHOLD...
BLR R14 NO, RETURN INDICATING NO MATCH
LA R15,4 YES, INDICATE MATCH
BR R14 RETURN TO CALLER
SPACE 1
WSTCLC CLC 0(*-*,R1),0(R8) *** EXECUTE ONLY ***
SPACE 1
DROP R6,R13 SUSPEND LOCAL & PCE ADDRESSABILITY