You can change the default data set names for these files by updating and implementing the appropriate section in the initialization CLIST. You can set one default for all users or set different defaults for individual users.

Whether you use the system settings or define your own values, the NPF interface will retrieve the defaults at the start of an interactive session and display them on the panels. These values represent the actual data sets the interface will access. The users can change to other data sets by keying over the displayed values or they can go back to the initial defaults by clearing the fields.

To change the defaults, copy hlq.SEZAINST(NPFINIT) into your system CLIST library and make changes by following the instructions for this section.

You can run this CLIST as a stand-alone process or invoke it from the ISPF Primary Option Menu. See Updating ISR@PRIM processing section for instructions on invoking it from the menu.

PROC 0
CONTROL NOFLUSH NOMSG MAIN
/*********************************************************************/
/*                                                                   */
/*  CLIST NAME:      NPFINIT                                         */
/*                                                                   */
/*  COPYRIGHT = NONE.                                                */
/*                                                                   */
/*  SMP/E Distribution Name: EZAEC050                                */
/*                                                                   */
/*  DESCRIPTION:                                                     */
/*     This is a sample CLIST which does initialization processing   */
/*     for NPF's ISPF panel interface and then invokes the NPF main  */
/*     panel.  This CLIST can be modified as necessary to match      */
/*     specific installation requirements.                           */
/*                                                                   */
/*     This CLIST can be invoked via a stand-alone TSO command,      */
/*     or it can be invoked from the system's main ISPF panel.       */
/*                                                                   */
/*     Much of the code within this CLIST is optional and can be     */
/*     deleted if desired.  This optional code is divided into       */
/*     3 sections as follows:                                        */
/*                                                                   */
/*     *  Section 1:  Sets up default file names for routing,        */
/*        options, queue and trace file processing on NPF's ISPF     */
/*        panel interface.  For access to each type of file, the     */
/*        default name will be used when no previously-used name     */
/*        for that file has been saved by the current user id.       */
/*                                                                   */
/*     *  Section 2:  Allocates the libraries containing the panels  */
/*        and modules required by NPF's ISPF panel interface.        */
/*                                                                   */
/*     *  Section 3:  Restores the ISPF environment by deallocating  */
/*        the libraries allocated by the code in Section 2.          */
/*                                                                   */
/*     Set the &DODFLTS variable to 'Y' or 'N' to indicate           */
/*     whether the default-setting logic should be executed.         */
/*                                                                   */
/*     Set the &DOLIBS variable to 'Y' or 'N' to indicate            */
/*     whether the library-allocation logic should be executed.      */
/*                                                                   */
/*********************************************************************/
  SET &DODFLTS = Y                  /* Set defaults                  */
  SET &DOLIBS = N                   /* Do not allocate libraries     */
/*********************************************************************/
/*                                                                   */
/*         O P T I O N A L   C O D E   -   S E C T I O N   1         */
/*                                                                   */
/*  The code in this section initializes default file names for      */
/*  NPF's routing, options, queue and/or trace files.  These default */
/*  names can be set the same for all users, or they can be set to   */
/*  different values for different user ids.                         */
/*                                                                   */
/*  If this section is deleted or bypassed, NPF's panel code         */
/*  will set its own hard-coded default values as documented in      */
/*  the NPF manual.                                                  */
/*                                                                   */
/*  Notes:                                                           */
/*                                                                   */
/*  1. The &CLSTUPDT# variable below controls whether this CLIST's   */
/*     default-setting logic is executed or bypassed when the CLIST  */
/*     gets control under a particular user id:                      */
/*                                                                   */
/*     *  Set &CLSTUPDT# to a new and higher value each time this    */
/*        CLIST's default-setting logic is changed.                  */
/*                                                                   */
/*     *  As each user id executes the CLIST, the &CLSTUPDT# value   */
/*        will be compared to the value saved when that user id's    */
/*        defaults were last updated:                                */
/*                                                                   */
/*        -  An updated &CLSTUPDT# value will cause the CLIST to     */
/*           execute its default-setting logic.                      */
/*                                                                   */
/*        -  An unchanged &CLSTUPDT# value will cause the CLIST      */
/*           to bypass ist default-setting logic.                    */
/*                                                                   */
/*  2. This sample CLIST assumes that you want default file          */
/*     names as follows:                                             */
/*                                                                   */
/*     *  For the routing file:                                      */
/*        - For user id = USER6, file name = XYZ.PERS.ROUTING        */
/*        - For all other users, file name = TCPIP.NPF.ROUTING       */
/*                                                                   */
/*     *  For the options file:                                      */
/*        - For user id = USER6, file name = XYZ.PERS.OPTIONS        */
/*        - For all other users, file name = TCPIP.NPF.OPTIONS       */
/*                                                                   */
/*     *  For the queue file:                                        */
/*        - For user id = USER2 or USER3 or USER17,                  */
/*                               file name = ABC.ACCT.QUEUE          */
/*        - For user id = USER5, file name = PQR.PAYROLL.QUEUE       */
/*        - For user id = USER6, file name = XYZ.PERS.QUEUE          */
/*        - For all other users, file name = TCPIP.NPF.QUEUE         */
/*                                                                   */
/*     *  For the trace file:                                        */
/*        - For all users,       file name = userid.NPF.TRACE        */
/*                                                                   */
/*********************************************************************/
IF &DODFLTS = Y THEN +
  DO
    SET &CLSTUPDT# = 1                /* Set current update number   */
    ISPEXEC VGET NPFUPDT# PROFILE     /* Get last-saved update number*/
    IF &NPFUPDT# ^= &CLSTUPDT# THEN +
      DO
        SET &NPFUPDT# = &CLSTUPDT#    /* Save the current            */
        ISPEXEC VPUT NPFUPDT# PROFILE /* ... update number value     */
        /*-----------------------------------------------------------*/        
        /*   Set defaults applicable to most or all user ids         */
        /*-----------------------------------------------------------*/        
        SET &NPFDFLTR = TCPIP.NPF.ROUTING
        SET &NPFDFLTO = TCPIP.NPF.OPTIONS
        SET &NPFDFLTT = &SYSUID..NPF.TRACE
        /*---------------------------------------------------------*/          
        /*   Set defaults for single user ids or sets of user ids  */
        /*---------------------------------------------------------*/          
        SELECT (&SYSUID)
          WHEN (USER2 | USER3 | USER17) +
            SET &NPFDFLTQ = ABC.ACCT.QUEUE
          WHEN (USER5) +
            SET &NPFDFLTQ = PQR.PAYROLL.QUEUE
          WHEN (USER6) +
            DO
              SET &NPFDFLTR = XYZ.PERS.ROUTING
              SET &NPFDFLTO = XYZ.PERS.OPTIONS
              SET &NPFDFLTQ = XYZ.PERS.QUEUE
            END
          OTHERWISE +
            SET &NPFDFLTQ = TCPIP.NPF.QUEUE
        END                           /* End of SELECT               */
        /*-----------------------------------------------------------*/        
        /*  Save the default values in the user id's Profile pool    */
        /*-----------------------------------------------------------*/        
        ISPEXEC VPUT (NPFDFLTR NPFDFLTO NPFDFLTQ NPFDFLTT) PROFILE
      END
  END
/*********************************************************************/
/*                 E N D   O F   S E C T I O N   1                   */
/*********************************************************************/
/*********************************************************************/
/*                                                                   */
/*         O P T I O N A L   C O D E   -   S E C T I O N   2         */
/*                                                                   */
/*  The code in this section allocates the libraries required by     */
/*  NPF's ISPF panel interface.                                      */
/*                                                                   */
/*  Note:  This library-allocation function can also be accomplished */
/*  by adding appropriate DD cards to each user id's TSO logon       */
/*  procedure.  If that technique is used, the code in Sections 2    */
/*  and 3 should be bypassed or deleted from this CLIST.             */
/*                                                                   */
/*********************************************************************/
IF &DOLIBS = Y THEN +
  DO
    /*---------------------------------------------------------------*/        
    /*   NPF libraries concatentation                                */
    /*---------------------------------------------------------------*/        
    ISPEXEC LIBDEF ISPPLIB DATASET ID('TCPIP.SEZAPENU') COND
    ISPEXEC LIBDEF ISPMLIB DATASET ID('TCPIP.SEZAMENU') COND
  END                                                                          
/*********************************************************************/
/*                 E N D   O F   S E C T I O N   2                   */
/*********************************************************************/
/*-------------------------------------------------------------------*/        
/*                    R E Q U I R E D   C O D E                      */
/*-------------------------------------------------------------------*/        
ISPEXEC SELECT PANEL(EZAPPMP)      /* Invoke the NPF main panel      */
/*********************************************************************/
/*                                                                   */
/*         O P T I O N A L   C O D E   -   S E C T I O N   3         */
/*                                                                   */
/*  The code in this section restores the ISPF library environment   */
/*                                                                   */
/*  Note:  This section is required if Section 2 is present, but     */
/*  should be bypassed or deleted if Section 2 is bypassed or deleted*/
/*                                                                   */
/*********************************************************************/
IF &DOLIBS = Y THEN +
  DO
    /*---------------------------------------------------------------*/        
    /*   Restore the ISPF environment                                */
    /*---------------------------------------------------------------*/        
    ISPEXEC LIBDEF ISPPLIB
    ISPEXEC LIBDEF ISPMLIB
  END                                                                          
/*********************************************************************/
/*                 E N D   O F   S E C T I O N   3                   */
/*********************************************************************/
/*-------------------------------------------------------------------*/        
/*                    R E Q U I R E D   C O D E                      */
/*-------------------------------------------------------------------*/        
RETURN                             /* Return to invoker              */