/***************************************************************/
/* PROGRAM . . . :    SEUEDITCTL                               */
/* TYPE  . . . . :    CL Program                               */
/*                                                             */
/* FUNCTION  . . :    To restrict editing using ADTS utilities */
/*                    during the RTCi/RTCP build               */
/*                                                             */
/* PARAMETERS                                                  */
/* 1. SRCLIB  CHAR(10)                                         */
/* 2. SRCFILE CHAR(10)                                         */
/* 3. SRCMBR  CHAR(10)                                         */
/* 4. CONTROL CHAR(1)  OUTPUT                                  */
/***************************************************************/
             PGM        PARM(&SRCLIB &SRCFILE &SRCMBR &CONTROL) /* +
                          TO CONTROL SEU EDITING VIA EXIT POINT */

             DCL        VAR(&SRCLIB) TYPE(*CHAR) LEN(10) /* INPUT +
                          FROM SEU */
             DCL        VAR(&SRCFILE) TYPE(*CHAR) LEN(10) /* INPUT +
                          FROM SEU */
             DCL        VAR(&SRCMBR) TYPE(*CHAR) LEN(10) /* INPUT +
                          FROM SEU */
             DCL        VAR(&CONTROL) TYPE(*CHAR) LEN(1)  +
                          /* OUTPUT FROM USER TO SEU '2'=DISALLOW EDIT  +
                          Any others = ALLOW  EDIT */
             DCL        VAR(&USR) TYPE(*CHAR) LEN(10)
             DCL        VAR(&SYSADMIN) TYPE(*CHAR) VALUE('SMITHJ')


/*****************************************************************/
/* Retrieve the user profile.  If it is the system administrator */
/* allow the editing.                                            */
/*****************************************************************/
             RTVUSRPRF  USRPRF(*CURRENT) RTNUSRPRF(&USR)
             IF         COND(&USR *EQ &SYSADMIN) THEN(GOTO +
                          CMDLBL(ALLOW))

/*****************************************************************/
/* Allow library and file QGPL/QCLSRC                            */
/*****************************************************************/
             IF         COND((&SRCLIB *EQ 'QGPL      ') +
                           & (&SRCFILE *EQ 'QCLSRC    ')) +
                        THEN(GOTO CMDLBL(ALLOW))

/*****************************************************************/
/* If we reach here, editing is disallowed.                      */
/* Set the allow flag to '2' to disallow editing.                */
/*****************************************************************/
             CHGVAR     VAR(&CONTROL) VALUE('2') /* DISALLOW EDITING */

/*****************************************************************/
/* Send a message to the joblog so that it is clear that the     */
/* exit program has disallowed the editing.                      */
/*****************************************************************/
             SNDPGMMSG  MSG(&SRCLIB *TCAT '/' *CAT &SRCFILE *TCAT +
                          '/' *CAT &SRCMBR *TCAT ' editing disallowed +
                          for' *BCAT &USR *BCAT 'by Exit Program')

ALLOW:  ENDPGM