INFDS Open Feedback Example

To specify an INFDS which contains fields in the open feedback section, you can make the following entries:

Specify the INFDS keyword on the file description specification with the name of the file information data structure
Specify the file information data structure and the subfields you wish to use on a definition specification.
Use information in the iSeries Information Center database and file systems category to determine which fields you wish to include in the INFDS. To calculate the From and To positions (positions 26 through 32 and 33 through 39 of the definition specifications) that specify the subfields of the open feedback section of the INFDS, use the Offset, Data Type, and Length given in the Information Center and do the following calculations:
```
   From = 81 + Offset
   To = From - 1 + Character_Length
   Character_Length = Length (in bytes)
```
For example, for overflow line number of a printer file, the Information Center gives:
```
   Offset = 107
   Data Type is binary
   Length = 2
Therefore,
   From = 81 + 107 = 188,
   To = 188 - 1 + 2 = 189.
   See subfield OVERFLOW in example below
```

Figure 31. Example of Coding an INFDS with Open Feedback Information

FFilename++IPEASFRlen+LKlen+AIDevice+.Keywords+++++++++++++++++++++++++++++Comments++++++++++
FMYFILE    O    F  132        PRINTER INFDS(OPNFBK)
DName+++++++++++ETDsFrom+++To/L+++IDc.Keywords+++++++++++++++++++++++++++++Comments++++++++++
DOPNFBK           DS
D ODP_TYPE               81     82                                         * ODP Type
D FILE_NAME              83     92                                         * File name
D LIBRARY                93    102                                         * Library name
D SPOOL_FILE            103    112                                         * Spool file name
D SPOOL_LIB             113    122                                         * Spool file lib
D SPOOL_NUM_OLD         123    124I 0                                      * Spool file num
D RCD_LEN               125    126I 0                                      * Max record len
D KEY_LEN               127    128I 0                                      * Max key len
D MEMBER                129    138                                         * Member name
D TYPE                  147    148I 0                                      * File type
D ROWS                  152    153I 0                                      * Num PRT/DSP rows
D COLUMNS               154    155I 0                                      * Num PRT/DSP cols
D NUM_RCDS              156    159I 0                                      * Num of records
D SPOOL_NUM             160    163I 0                                      * 6 digit Spool Nbr
D VOL_OFF               184    185I 0                                      * Vol label offset
D BLK_RCDS              186    187I 0                                      * Max rcds in blk
D OVERFLOW              188    189I 0                                      * Overflow line
D BLK_INCR              190    191I 0                                      * Blk increment
D FLAGS1                196    196                                         * Misc flags
D REQUESTER             197    206                                         * Requester name
D OPEN_COUNT            207    208I 0                                      * Open count
D BASED_MBRS            211    212I 0                                      * Num based mbrs
D FLAGS2                213    213                                         * Misc flags
D OPEN_ID               214    215                                         * Open identifier
D RCDFMT_LEN            216    217I 0                                      * Max rcd fmt len
D CCSID                 218    219I 0                                      * Database CCSID
D FLAGS3                220    220                                         * Misc flags
D NUM_DEVS              227    228I 0                                      * Num devs defined

[ Top of Page | Previous Page | Next Page | Contents | Index ]