原始ステートメント入力ユーティリティー (SEU) の使用

ソース・ステートメントを入力するために、原始ステートメント入力ユーティリティー (SEU) を 使用することができます。 また、SEU は構文検査だけでなく異なる仕様書のテンプレートのプロンプトを提 供します。 SEU の開始には、STRSEU (原始ステートメント入力ユーティリティー開始) コマンドを使用します。 これ以外の SEU の開始方法および使用方法については 、「AS/400 適用業務開発ツールセット AS/400 用 原始ステートメント入力ユーティリティー 使用者の手引きと参照」マニュアルを参照してください。

クライアント・ツールの開始について詳しくは、『クライアント製品での アプリケーション開発ツールの使用』を参照してください。

ソース・ファイルを QRPGLESRC と名前を付けた場合には、SEU は 新しいメンバーの編集セッションを開始する時にソース・タイプを RPGLE に 自動的に設定します。 そうでない場合は、メンバーを作成する時に RPGLE を指定する必要が あります。

STRSEU の入力の後にプロンプトの必要がある場合には、F4 キーを押 してください。 STRSEU 画面が表示され、パラメーターをリストし、デフォルトの値を提示します。 プロンプトを要求する前にパラメーター値を指定した場合には、その値の 入った画面が表示されます。

次の例では、マスター・ファイルから社員情報を印刷するプログラムのため のソース・ステートメントを入力します。 この例では、以下のことを行う方法を示しています。

  1. MYLIB というライブラリーを作成には、次の入力をします。
    CRTLIB LIB(MYLIB)

    CRTLIB コマンド が MYLIB というライブラリーを作成します。

  2. QRPGLESRC というソース物理ファイルを作成するには、次の入力をします。
    CRTSRCPF FILE(MYLIB/QRPGLESRC) RCDLEN(112)
    TEXT('Source physical file for ILE RPG programs')

    CRTSRCPF コマンドは、ライブラリー MYLIB にソース物理ファイル QRPGLESRC を 作成します。

  3. 編集セッションを開始し、ソース・メンバー EMPRPT を作成するには、次のよ うに入力してください。
    STRSEU SRCFILE(MYLIB/QRPGLESRC)
    SRCMBR(EMPRPT)
    TYPE(RPGLE) OPTION(2)

    OPTION(2) の入力は、新しいメンバーのセッションを開始したい ことを指示します。STRSEU コマンドは新しいメンバー EMPRPT をライブラリー MYLIB のファイル QRPGLESRC に作成し、編集セッションを開始します。

    SEU 編集画面が図 27 に示すように表示されます。 6 桁目 (仕様書タイプ) が左端になるように、 画面が自動的にシフトされることに 注意してください。

    図 27. 新しいメンバーの編集画面
     桁  . . . . . :    6  76            編集                       MYLIB/QRPGLESRC
     SEU==>  ___________________________________________________________     EMPRPT
     FMT H  HKEYWORDS++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
            *************** データの始め ***************  
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
    '''''''
            ****************** データの終わり **************************************
     F3=終了   F4=プロンプト   F5=最新表示   F9=コマンドの複写   F10=カーソル   F11=切り替え 
     F16=検索の反復            F17=変更の反復                    F24=キーの続き
    メンバー EMPRPT がファイル MYLIB/QRPGLESRC に追加された。                              +
  4. プロンプトを出すためには、次の SEU 接頭部コマンドを 使って、SEU 編集画面に以下のソース・ステートメントを入力してください。
    図 28. EMPRPT メンバーのソース・ステートメント
          *===============================================================*
          * モジュール名:    EMPRPT
          * 関連ファイル:    EMPMST   (物理ファイル)
          *                  QSYSPRT  (PRINTER ファイル)
          * 説明:            このプログラムはファイル EMPMST から
          *                  社員情報を印刷します。
          *===============================================================*
         FQSYSPRT   O    F   80        PRINTER
         FEMPMST    IP   E           K DISK
         D TYPE            S              8A
         D EMPTYPE         PR             8A
         D   CODE                         1A
         IEMPREC        01
         C                   EVAL      TYPE = EMPTYPE(ETYPE)
         OPRINT     H    1P                     2  6
         O                                           50 'EMPLOYEE INFORMATION'
         O          H    1P
         O                                           12 'NAME'
         O                                           34 'SERIAL #'
         O                                           45 'DEPT'
         O                                           56 'TYPE'
         O          D    01
         O                       ENAME               20
         O                       ENUM                32
         O                       EDEPT               45
         O                       TYPE                60
          * プロシージャー EMPTYPE は、パラメーター CODE によって
          * 示された社員タイプを表すストリングを戻します。
         P EMPTYPE         B
         D EMPTYPE         PI             8A
         D   CODE                         1A
         C                   SELECT
         C                   WHEN      CODE = 'M'
         C                   RETURN    'Manager'
         C                   WHEN      CODE = 'R'
         C                   RETURN    'Regular'
         C                   OTHER
         C                   RETURN    'Unknown'
         C                   ENDSL
         P EMPTYPE         E
  5. F3 (終了) を押して終了画面に行きます。EMPRPT を保管するためには、Y (はい) をタイプしてください。

    メンバー EMPRPT が保管されます。

図 29 は、EMPRPT ソースによって参照される DDS を示したものです。

図 29. EMPRPT の DDS
     A*****************************************************************
     A* 説明:  これは物理ファイル EMPMST の DDS です。                *
     A*        これには 1 つのレコード様式 EMPREC が入っています。    *
     A*        このファイルには、会社の各社員ごとに 1 レコードが      *
     A*        入っています。                                         *
     A*****************************************************************
     A*
     A          R EMPREC
     A            ENUM           5  0       TEXT('EMPLOYEE NUMBER')
     A            ENAME         20          TEXT('EMPLOYEE NAME')
     A            ETYPE          1          TEXT('EMPLOYEE TYPE')
     A            EDEPT          3  0       TEXT('EMPLOYEE DEPARTMENT')
     A            ENHRS          3  1       TEXT('EMPLOYEE NORMAL WEEK HOURS')
     A          K ENUM

このソース・ステートメントからプログラムを作成するには、 DFTACTGRP(*NO) を指定して CRTBNDRPG コマンドを使用してください。



[ ページのトップ | 前ページ | 次ページ | 目次 | 索引 ]