WDWBORDER (Window Border) keyword for display files

You use this file-level or record-level keyword to specify the color, display attributes, and characters used to form the border of a window.

The format of the keyword is:

WDWBORDER([color] [display-attribute] [characters])

At least one parameter must be specified.

The color parameter specifies the color of the border characters on a color display station (3179 Models C1 and C2, 5292 Color display stations only, or 5555 Models C01 and F01). The parameter is specified as an expression of the form (*COLOR value).

The valid values for the color parameter are:

Value: Meaning
BLU: Blue
GRN: Green
WHT: White
RED: Red
TRQ: Turquoise
YLW: Yellow
PNK: Pink

If the color parameter is not specified, the default is BLU. This parameter is ignored if it is specified for a window on a monochrome display.

The display-attribute parameter specifies the display attributes of the border characters. The parameter is specified as an expression of the form (*DSPATR [value1 [value2 [value3...]]]). If more than one DSPATR value is used, they are combined to form one DSPATR that is used for the entire border.

The valid values for the display-attributes values are:

Value: Meaning
BL: Blink
CS: Column separator
HI: High intensity
ND: Nondisplay
RI: Reverse image
UL: Underline

There is no default for display-attributes.

Note: Display-attributes CS, HI, and BL can cause fields on 5292, 3179, and 3197 Model C1 and C2 display stations to appear as color fields. Display-attributes HI, RI, and UL cause a border not to be displayed.

The characters parameter specifies the characters that make up the border. The parameter is specified as an expression of the form (*CHAR 'border-characters'). The border character value is an 8-character string that defines the border characters in the following order:

top-left-corner
top-border
top-right-corner
left-border
right-border
bottom-left-corner
bottom-border
bottom-right-corner

If this parameter is not specified, the default border characters are period (.) for the upper-left and right corners and the top and bottom borders, colon (:) for the left and right borders and lower-left and right corners. Although any displayable character can be specified as a border character, it is recommended that you use invariant characters.

The following table shows the invariant characters:

Table 1. Character set for system data
Hexadecimal	Character	Description
40		Blank
4B	.	Period
4C	<	Less than sign
4D	(	Left parenthesis
4E	+	Plus sign
50	&	Ampersand
5C	*	Asterisk
5D	)	Right parenthesis
5E	;	Semicolon
60	-	Minus sign
61	/	Slash
6B	,	Comma
6C	%	Percent sign
6D	_	Underline
6E	>	Greater than sign
6F	?	Question mark
7A	:	Colon
7D	'	Single quotation mark
7E	=	Equal sign

Note: In addition, you can use any of the following characters:

Uppercase alphabetic characters: A through Z
Numeric characters: 0 through 9

If the WDWBORDER keyword is specified at the record level, the WINDOW or PULLDOWN keyword must also be specified on the same record. If a WINDOW keyword that references another window is also specified, a warning message is issued.

Option indicators are valid for this keyword.

You can specify more than one WDWBORDER on a record. If you specify the WDWBORDER keyword more than once at the file level or at a record level, the parameters for the keywords that are in effect are combined on the same level. If different values are specified for the same parameter, the parameter value of the first keyword is used.

If the WDWBORDER keyword is specified both at the file level and on a window or pull-down definition record, the parameter values defined at both levels are combined. If different values are specified for the same parameter, the parameter value at the record level is used.

Example

The following example shows how to specify the WDWBORDER keyword.

|...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....8
     A  01                                  WDWBORDER((*COLOR PNK) +
     A                                      (*DSPATR BL))
     A          R RECORD1                   WINDOW(6 15 9 30)
     A N01                                  WDWBORDER((*COLOR GRN))
     A  01                                  WDWBORDER((*COLOR RED))
     A            FIELD1         5A  B  2  2
     A            FIELD2        20A  B  8  5
     A          R RECORD2                   WINDOW(8 20 9 30)
     A                                      WDWBORDER((*COLOR YLW) +
     A                                       (*DSPATR RI))
     A            FIELD3         5A  B  2  2
     A            FIELD4        20A  B  8  5
     A            LINE           2S 0P
     A            POS            2S 0P
     A          R RECORD3                   WINDOW(&LINE &POS 9 30)
     A                                      WDWBORDER((*CHAR +
     A  02                                   '+-+||+-+'))
     A            FIELD3         5A  B  2  2
     A            FIELD4        20A  B  8  5
     A            LINE           2S 0P
     A            POS            3S 0P
     A

If the window defined by RECORD1 is written to the display with indicator 01 set off, it has a green border constructed of colons for the vertical borders and periods for the horizontal borders. If indicator 01 is set on, the window has a blinking red border.

When the window defined by RECORD2 is written to the display, it has a yellow border displayed in reverse image constructed of the default border characters.

When the window defined by RECORD3 is written to the display, the following output appears:

If indicator 02 is set on and indicator 01 is off, the window has a blue border constructed of dashes for the top and bottom borders, vertical bars for the left and right borders, and plus signs for the corners.
If indicator 02 is set off and indicator 01 is set on, the window has a pink border.
If indicators 01 and 02 are on, the window has a pink border constructed of dashes for the top and bottom borders, vertical bars for the left and right borders, and plus signs for the corners.