MDTOFF (Modified Data Tag Off) keyword for display files

You use this record-level keyword with the OVERLAY keyword to set off modified data tags (MDTs) for input-capable fields in record formats already on the display.

The format of the keyword is:

MDTOFF[(*UNPR | *ALL)]

The MDTs are set off when your program sends an output operation to the record format you are defining.

To set off MDTs for unprotected fields only (those without the DSPATR(PR) keyword in effect), specify the *UNPR parameter value (this is also the default if no parameter value is specified). To set off MDTs for all input-capable fields, specify the *ALL parameter value.

Your program can select the DSPATR(MDT) keyword for fields in the same record format for which it selects MDTOFF (any parameter). If so, these fields are displayed with their MDTs set on.

The ERASEINP(*ALL) keyword implies MDTOFF(*UNPR) unless MDTOFF(*ALL) is specified.

If the ERASEINP(*MDTON) keyword is specified with MDTOFF(*ALL), the end effect is as if the ERASEINP(*ALL) keyword and MDTOFF(*ALL) are both specified. This is also true if the ERASEINP keyword is specified with no parameter value.

Option indicators are valid for this keyword.

MDTOFF is not valid for the subfile record format (identified by the SFL keyword). It is valid for all other record formats for which OVERLAY keyword is also specified.

Example

The following example shows how to specify the MDTOFF keyword.

|...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....8
00010A          R RECORD1                   OVERLAY MDTOFF
00020A            FLD1           6   B  2  2
00030A            FLD2           6   B  3  2
00040A*
00050A          R RECORD2                   OVERLAY MDTOFF(*UNPR)
00060A            FLD21          6   B  4  2
00070A            FLD22          6   B  5  2
00080A*
00090A          R RECORD3                   OVERLAY MDTOFF(*ALL)
00100A            FLD31          6   B  6  2
00110A            FLD32          6   B  7  2
00120A            FLD33          6   B  8  2DSPATR(PR)
     A

RECORD1 and RECORD2 have equivalent MDTOFF keyword specifications. When RECORD1 or RECORD2 is displayed, the MDT of each input-capable field already on the display is set off, unless the field has the DSPATR(PR) keyword in effect (FLD33, when displayed, is such a field). When RECORD3 is displayed, the MDTs of each input-capable field already on the display is set off even if the DSPATR(PR) keyword is in effect for the field.