Display conflict and relaxation information for infeasible models using OPL script

The following sample shows one such approach for a simple model:


dvar int x1 in 0..40;
dvar int+ x2;
dvar int+ x3;
maximize x1 + 2*x2 - 3*x3;
subject to{
  c1:  x2 + x3 <= 20;
  c2: x1 - 3*x2 + x3 <= 30;
  c3: x1 <= 20;
  c4: x1 >= 40;
}
main{
 thisOplModel.generate();
 if(cplex.solve()){
  writeln("Solve successful; solve status="+cplex.getCplexStatus());
  writeln("Objective value="+cplex.getObjValue());
 }  
 else{
  writeln("Solve failed; CPLEX status="+cplex.getCplexStatus());
  writeln("Calling printConflict (CONFLICT REFINER)");
  writeln(thisOplModel.printConflict());
  writeln("Printing conflicts using conflictIterator");
  var confIter = thisOplModel.conflictIterator;
  for(var x in confIter){
   writeln("Member name:"+x.ct.name);
   writeln("Conflict type:"+x.info);
  }    
  writeln("Calling printRelaxation (FEASOPT)");
  writeln(thisOplModel.printRelaxation());
  writeln("Printing relaxations using relaxationIterator");
  var relaxIter = thisOplModel.relaxationIterator;
  for(x in relaxIter){
   writeln("Member name:"+x.ct.name);
   writeln("Old bound:"+x.info);
   writeln("New bound:"+x.info2);
   writeln("Bound changed to:"+x.info3);
  }
 }
}