IBM Support

Bowker's test of symmetry in SPSS

Troubleshooting


Problem

Is it possible to compute Bowker's Test for symmetry with SPSS? This test is a generalization of McNemar's Test that allows for more than 2 categories.

Resolving The Problem

The Crosstabs procedure has an option to request the McNemar test. The Bowker test results will be printed if the McNemar test is requested in Crosstabs for a square table with 3 or more categories in each dimension. The McNemar test is requested in the graphic user interface (GUI) by clicking the Statistics button in the main Crosstabs dialog, then clicking the check-box for McNemar in the Statistics dialog. If you are using syntax commands, you can request the McNemar test by adding the keyword MCNEMAR to the /STATISTICS subcommand, as in:

CROSSTABS
/TABLES=res1980 BY res1985
/FORMAT= AVALUE TABLES
/STATISTIC=CHISQ MCNEMAR
/CELLS= COUNT
/COUNT ROUND CELL .

It is also possible to compute Bowker's symmetry test with the GENLOG procedure if you have the Advanced Models module for SPSS. You can test symmetry as a loglinear model in GENLOG, which is available in the menus under Analyze->Loglinear->General. GENLOG prints Likelihood ratio and Pearson chi-squares for goodness of fit of the model. Agresti (1990, p.354) states that the Pearson statistic for testing the fit of the symmetry model simplifies to Bowker's (1948) statistic, which is McNemar's test in the 2x2 case.

Agresti, A. (1990), Categorical data analysis, Wiley.
Bowker, A.H. (1948). A test for symmetry in contingency tables. Journal of American Statistical Association, 43, 572-574.


Example commands for a GENLOG test of symmetry are provided below. The data come from an example on p. 357 of Agresti. RES1980 and RES1985 are the categorical variables for which symmetry is tested. The computed variables S1 to QS34 are cell covariates that define the symmetry model. The data are entered in an aggregated format, with one case per cell in the contingency table. The variable WT holds the number of cases observed in each cell and is therefore designated as a weight variable in the WEIGHT command. For Bowker's test of symmetry, see the the Pearson chi-square and significance in the "Goodness-of-fit Statistics" section of the GENLOG output.

* Testing symmetry with GENLOG .
* Migration example from
* Alan Agresti (1990), "Categorical Data Analysis" pp 353-361 .

DATA LIST FREE / res1980 res1985 wt .
BEGIN DATA.
1 1 11607
1 2 100
1 3 366
1 4 124
2 1 87
2 2 13677
2 3 515
2 4 302
3 1 172
3 2 225
3 3 17819
3 4 270
4 1 63
4 2 176
4 3 286
4 4 10192
END DATA.
WEIGHT BY wt.

* Create the symmetry and quasi-symmetry indicator variables .
COMPUTE s1 = any(1,res1980,res1985).
COMPUTE s2 = any(2,res1980,res1985).
COMPUTE s3 = any(3,res1980,res1985).

COMPUTE qs12 = s1*s2 .
COMPUTE qs13 = s1*s3 .
COMPUTE qs14 = s1*any(4,res1980,res1985).
COMPUTE qs23 = s2*s3 .
COMPUTE qs24 = s2*any(4,res1980,res1985).
COMPUTE qs34 = s3*any(4,res1980,res1985).

EXECUTE.
FORMATS s1 to qs34 (F4).

* Symmetry model - reported in Agresti, page 357 .
GENLOG
res1980 res1985 WITH s1 s2 s3 qs12 qs13 qs14 qs23 qs24 qs34
/PRINT FREQ ESTIM
/PLOT NONE
/DESIGN qs12 qs13 qs14 qs23 qs24 qs34 s1 s2 s3 .


If you run the Crosstabs procedure with the McNemar test on RES1980 and RES1985, you will see that the chi-square values and significance levels match the symmetry test results from GENLOG.

[{"Product":{"code":"SSLVMB","label":"IBM SPSS Statistics"},"Business Unit":{"code":"BU059","label":"IBM Software w\/o TPS"},"Component":"Not Applicable","Platform":[{"code":"PF025","label":"Platform Independent"}],"Version":"Not Applicable","Edition":"","Line of Business":{"code":"LOB10","label":"Data and AI"}}]

Historical Number

22067

Document Information

Modified date:
16 April 2020

UID

swg21477019